使用ASP在IIS創(chuàng)建WEB站點(diǎn)的函數(shù)
'=============================================================
'函數(shù)介紹：創(chuàng)建WebSite
'本函數(shù)使用ADSI，需要Administrators組用戶權(quán)限
'函數(shù)名稱：CreateWebSite(Computer,IPAddr,PortNum,HostName,WebSiteDirectory,LogDirectory,WebSiteInfo,GuestUserName,GuestUserPass,StartOrStop)
'用法：CreateWebSite 計(jì)算機(jī)名(一搬為LocalHost或127.0.0.1),站點(diǎn)IP地址,端口號,主機(jī)名,站點(diǎn)根目錄,,LOG文件的目錄站點(diǎn)說明,網(wǎng)站訪問時(shí)所使用的帳號,網(wǎng)站訪問時(shí)所用帳號的口令,是否啟動站點(diǎn)
'例：CreateWebSite "LocalHost","127.0.0.123","80","http://www.test.net","E:/UserData/UserNum001","E:/UserData/UserNum001/LogFiles","wwwtest.net","IUSR_Num001_test.net","abc888",True' target=_blank>www.test.net","E:\UserData\UserNum001","E:\UserData\UserNum001\LogFiles","wwwtest.net","IUSR_Num001_test.net","abc888",True
'=============================================================
Function CreateWebSite(Computer,IPAddr,PortNum,HostName,WebSiteDirectory,LogDirectory,WebSiteInfo,GuestUserName,GuestUserPass,StartOrStop)
Dim w3svc, WebServer, NewWebServer, NewDir
Dim Bindings, BindingString, NewBindings, SiteNum, SiteObj, bDone
On Error Resume Next
Err.Clear
'檢測是否能夠加載W3SVC服務(wù)（即WEB服務(wù)）
Set w3svc = GetObject("IIS://" & Computer & "/w3svc")
If Err.Number <> 0 Then '顯示錯(cuò)誤提示
  response.write "無法打開: "&"IIS://" & Computer & "/w3svc"
  response.end
End If
'檢測是否有設(shè)定相同IP地址、端口及主機(jī)名的站點(diǎn)存在
BindingString = IPAddr & ":" & PortNum & ":" & HostName
For Each WebServer in w3svc
  If WebServer.Class = "IIsWebServer" Then
  Bindings = WebServer.ServerBindings
   If BindingString = Bindings(0) Then
    response.write "IP地址沖突:" & IPAddr & ",請檢測IP地址！."
    Exit Function
   End If
  End If
Next

'確定一個(gè)不存在的站點(diǎn)編號做為新建站點(diǎn)編號，系統(tǒng)默認(rèn)WebSite站點(diǎn)編號為1，因此從2開始
SiteNum=2
bDone = False
While (Not bDone)
Err.Clear
Set SiteObj = GetObject("IIS://"&Computer&"/w3svc/"&SiteNum) '加載指定站點(diǎn)
If (Err.Number = 0) Then
  'response.write " Step_1站點(diǎn)"&SiteNum&"存在"
  SiteNum = SiteNum + 1
Else
  'response.write " Step_1站點(diǎn)"&SiteNum&"不存在"
  Err.Clear
  Set NewWebServer = w3svc.Create("IIsWebServer",SiteNum) '創(chuàng)建指定站點(diǎn)
  If (Err.Number <> 0) Then
   'response.write " Step_2站點(diǎn)"&SiteNum&"創(chuàng)建失敗"
   SiteNum = SiteNum + 1
  Else
   'response.write " Step_2站點(diǎn)"&SiteNum&"創(chuàng)建成功"
   bDone = True
  End If
End If
If (SiteNum > 50) Then '服務(wù)器最大創(chuàng)建站點(diǎn)數(shù)
  response.write "超出服務(wù)器最大創(chuàng)建站點(diǎn)數(shù)，正在創(chuàng)建的站點(diǎn)的序號為： "&SiteNum&"."
  response.end
End If
Wend

'進(jìn)行站點(diǎn)基本配置
NewBindings = Array(0)
NewBindings(0) = BindingString
NewWebServer.ServerBindings = NewBindings
NewWebServer.ServerComment= WebSiteInfo
NewWebServer.AnonymousUserName= GuestUserName
NewWebServer.AnonymousUserPass= GuestUserPass
NewWebServer.KeyType = "IIsWebServer"
NewWebServer.FrontPageWeb = True
NewWebServer.EnableDefaultDoc = True
NewWebServer.DefaultDoc = "Default.htm, Default.asp, Index.htm, Index.asp"
NewWebServer.LogFileDirectory= LogDirectory
NewWebServer.SetInfo
Set NewDir = NewWebServer.Create("IIsWebVirtualDir", "ROOT")
NewDir.Path = WebSiteDirectory
NewDir.AccessRead = true
NewDir.AppFriendlyName = "應(yīng)用程序" & WebSiteInfo
NewDir.AppCreate True
NewDir.AccessScript = True
Err.Clear
NewDir.SetInfo
If (Err.Number <> 0) Then
  response.write "主目錄創(chuàng)建時(shí)出錯(cuò)."
  response.end
End If
If StartOrStop = True Then
  Err.Clear
  Set NewWebServer = GetObject("IIS://" & Computer & "/w3svc/" & SiteNum)
  NewWebServer.Start
  If Err.Number <> 0 Then
   response.write "啟動站點(diǎn)時(shí)出錯(cuò)!"
   response.end
   Err.Clear
  End If
End If
response.write "站點(diǎn)創(chuàng)建成功，站點(diǎn)編號為："& SiteNum &" ，域名為："& HostName
End Function